Bohrův model atomu vodíku

Model atomu navržený Bohrem je kombinací představ klasické fyziky a ideou kvantovaní energie zavedené Planckem. Základem jsou tři postuláty:

	1. Elektron se pohybuje kolem jádra po stabilní kruhové orbitě bez toho, že by vyzařoval energii ve formě elekromagnetického záření
	2. Moment hybnosti elektronu nemůže nabývat libovolných hodnot, jeho hodnota je kvantovaná a to 
		l = m v r = n ℏ
	přitom n je přirozené číslo (tzv. hlavní kvantové číslo) a ℏ je Diracova konstanta:  ℏ = (h/(2  π)), h je Planckova konstanta
	3. Pokud elektron přejde z hladiny o vyšší energii (Subscript[e, i]) na hladinu nižší (Subscript[e, j]), emituje se foton, jehož energie hf odpovídá rozdílu energií hladin.
	hf = (Subscript[e, i]) - (Subscript[e, j])

Elektron je k jádru poután Coulombovou přitažlivou silou, která má pro jádro s jedním elektronem (vodíkový atom) tvar

(Subscript[F, c]) = -k ((e^2)/(r^2))

kde e je elementární náboj, r je vzdálenost elektronu od jádra, k je Coulombova konstanta

Našim úkolem bude odvodit závislost energie elektronu na kvantovém čísle n a frekvenci záření, které přísluší přechodu mezi dvěma energetickými hladinami

Výpočet rychlosti a vzdálenosti elektronu

Vyjdeme z předpokladu, že přitažlivá Coulombova síla musí být rovna odstředivé síle

coulomb = k  ((e^2)/(r^2));

odstrediva = m  ((v^2)/r);

rce1 = coulomb == odstrediva

Další rovnici získáme z Bohrovy kvantové podmínky pro moment hybnosti

moment = m v r;

rce2 = moment == n ℏ

Výrazy pro v a r získáme řešením soutavy rovnic rce1 a rce2

vysledek1 = Solve[{rce1, rce2}, {v, r}] // First

Energie n-té hladiny v atomu vodíku

Energie elektronu je dána součtem jeho potenciální a kinetické energie

kineticka = (1/2) m (v^2);

potencialni = -k ((e^2)/r);

celkova = kineticka + potencialni

Dosadíme za v a r a vyjádříme energii jako funkci kvantového čísla n

energie[n_] = celkova /. vysledek1 // Simplify

Hodnoty potřebných konstant získáme z balíku Fyzikální konstanty

Needs["Miscellaneous`PhysicalConstants`"];

hodnoty = {e -> ElectronCharge, m -> ElectronMass, 
          k -> (1/(4  π ϵ0)), ϵ0 -> 
            VacuumPermittivity, ℏ -> 
            PlanckConstantReduced};

Ve světě atomů se užívá jednotka energie elektronvolt (přibližně 1.602*(10^(-19)) J ), proto vyrobíme funkci, která bude udávat energii elektronu přímo v elketronvoltech

Needs["Miscellaneous`Units`"];

energieEV[n_] = 
      Convert[energie[n] //. hodnoty, ElectronVolt]

Zobrazení energetických hladin

Zobrazíme si do grafu prvních 10 energetických hladin atomu vodíku

Table[energieEV[n]/ElectronVolt, {n, 10}] // Evaluate

Plot[
        Table[energieEV[n]/ElectronVolt, {n, 10}] // Evaluate, {x, 0, 1}, 
        PlotRange -> All, Axes -> {False, True}];

Vidíme, že s rostoucím n se hladiny zhušťují a blíží k nule a teoreticky pro n->∞ se elektron stává volným- záporné hodnoty totiž udávají, že elektron je vázán k atomu, takže nejvíce je vázán elektron na hladině první, kde má energii:

energieEV[1]

To je zároveň energie, kterou je nutné dodat pro uvolnění elektronu z atomu

Frekvence záření emitovaného při přechodu elektronu

Frekvence záření je přímo úměrná rozdílu energií hladin mezi nimiž elektron přechází. Konstantou úměrnosti je Planckova konstanta.

rce3 = {h f == energie[ni] - energie[nj]} /. 
        h -> ℏ 2  π

frekvence = Solve[rce3, f] // First // Simplify

Vyjádříme též vlnovou délku příslušnou k dané frekvenci

c/f /. frekvence

Definujeme funkci vlnová délka s parametry (Subscript[n, i]) a (Subscript[n, j]).

vlndelka[ni_, nj_] = 
        Convert[(c/f /. frekvence) /. hodnoty /. 
              c -> SpeedOfLight /. ϵ0 -> 
              VacuumPermittivity, Nano Meter];

Například přechodem z 6 na 2 hladinu vznikne záření o vlnové délce

vlndelka[6, 2]

Lymanova série

Všechny možné přechody v atomu vodíku se řadí do tzv. sérií. Každou sérii určuje specifická hladina energie, z níž vycházejí přechody na vyšší hladiny, nebo na které končí přechody z vyšších hladin.
Lymanovu sérii, kterou si znázorníme, tvoří přechody na první hladinu z vyšších hladin

Table[vlndelka[n, 2], {n, 3, 10}]

Úkol

Balmerova série je tvořena přechody na druhou energetickou hladinu.
 Vypočtěte vlnové délky prvních sedmi čar a určete kolik se jich nachází ve viditelné části spektra